class_name CameraGimbal extends Node3D

@export var rotation_speed = (PI / 180) * 120
@export var shift_lock = false

var locked_mouse_positon = Vector2(0,0)
var mouse_locked = false
var mouse_x_velocity = 0
var mouse_y_velocity = 0

var zoom_min = 4
var zoom_max = 80
var zoom_speed = 20
var current_zoom = 8

func reset():
	basis = Basis()
	$InnerGimbal.basis = Basis()

func rotate_camera_y(y, delta):
	rotate_object_local(Vector3.UP, y * rotation_speed * delta)
func rotate_camera_x(x, delta):
	$InnerGimbal.rotate_object_local(
		Vector3.RIGHT, x * rotation_speed * delta)
	$InnerGimbal.rotation.x = clamp($InnerGimbal.rotation.x,-0.8,0.7)
	
func _input(event):
	if event is InputEventMouseMotion:
		mouse_x_velocity = event.relative.x
		mouse_y_velocity = event.relative.y
	elif event.is_action_pressed("zoom_out"):
		current_zoom += 1
	elif event.is_action_pressed("zoom_in"):
		current_zoom -= 1

func _process(delta):
 	# rotate outer gimbal around y axis
	var y = 0
	var x = 0

	if Input.is_action_just_pressed("shift_lock"):
		if shift_lock == true:
			shift_lock = false
		else:
			shift_lock = true
	elif Input.is_mouse_button_pressed(MOUSE_BUTTON_RIGHT) or shift_lock == true:
		if mouse_locked == false:
			mouse_locked = true
			locked_mouse_positon = get_viewport().get_mouse_position()
		Input.set_mouse_mode(Input.MOUSE_MODE_CAPTURED)

		if mouse_x_velocity > 5 or mouse_x_velocity < -5:
			y -= clamp(mouse_x_velocity / 12.5, -10, 10)
		if mouse_y_velocity > 5 or mouse_y_velocity < -5:
			x -= clamp(mouse_y_velocity / 12.5, -10, 10)
	else:
		Input.set_mouse_mode(Input.MOUSE_MODE_VISIBLE)
		mouse_locked = false
		mouse_x_velocity = 0
		mouse_y_velocity = 0

	rotate_camera_y(y, delta)
	rotate_camera_x(x, delta)

	# reset gimbals
	if Input.is_action_pressed("cam_reset"):
		reset()

	current_zoom = clamp(current_zoom, zoom_min, zoom_max)
	
	var pos = Vector3($InnerGimbal/Camera3D.position)
	pos.y = lerp(pos.y, float(current_zoom), zoom_speed*delta)
	pos.z = lerp(pos.z, float(current_zoom), zoom_speed*delta)
	
	$InnerGimbal/Camera3D.position = pos